# Maintainer: Kyle Manna <kyle[at]kylemanna[d0t]com>

_pkgname=yattag
pkgname=python-${_pkgname}
pkgver=1.15.2
pkgrel=1
pkgdesc='Python library for generating HTML or XML in a pythonic way.'
url='http://yattag.org'
depends=('python')
makedepends=('python-build'
             'python-installer'
             'python-setuptools'
             'python-wheel')
license=('LGPL')
arch=('any')
source=("https://pypi.python.org/packages/source/y/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('aad9f540bd22dc503e5b5506cc47856facf081aa71fd35f727371b63e1e402bf')

build() {
    cd "$srcdir/$_pkgname-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$srcdir/$_pkgname-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
    rm -rf ${pkgdir}/usr/lib/python3*/site-packages/tests/
}
