From ed20a37cc21b47055bcbb50285c3049b2320ae80 Mon Sep 17 00:00:00 2001
From: Mike Wilson <contact@mjwilson.org>
Date: Mon, 17 Aug 2026 12:20:58 -0400
Subject: [PATCH] Add redlib-git PKGBUILD

---
 src/redlib-git/PKGBUILD | 48 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 src/redlib-git/PKGBUILD

diff --git a/src/redlib-git/PKGBUILD b/src/redlib-git/PKGBUILD
new file mode 100644
index 0000000..178ecf5
--- /dev/null
+++ b/src/redlib-git/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: fossdd <fossdd@pwned.life>
+
+pkgname=redlib-git
+_pkgname=${pkgname%-git}
+pkgver=v0.29.4.r504.a4d36e9
+pkgrel=1
+pkgdesc="Private front-end for Reddit"
+url='https://github.com/redlib-org/redlib'
+license=(AGPL-3.0)
+arch=(x86_64)
+depends=()
+makedepends=(cargo git cmake make clang)
+provides=($_pkgname)
+conflicts=($_pkgname)
+backup=("etc/$_pkgname.conf")
+options=('!lto')
+source=("$pkgname::git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/$pkgname"
+	# Git, tags available
+	printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+	# Git, no tags available
+	# printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd $pkgname
+	export RUSTUP_TOOLCHAIN=stable
+	cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+	cd $pkgname
+	export RUSTUP_TOOLCHAIN=stable
+	export CARGO_TARGET_DIR=target
+	cargo build --release --all-features
+}
+
+package() {
+	cd "$pkgname"
+	install -Dm755 "target/release/$_pkgname" -t "$pkgdir/usr/bin/"
+	install -Dm644 'LICENSE' -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dm644 'README.md' -t "$pkgdir/usr/share/doc/$pkgname/"
+	install -Dm644 "contrib/$_pkgname.service" -t "$pkgdir/usr/lib/systemd/system/"
+	install -Dm644 "contrib/$_pkgname.conf" -t "$pkgdir/etc/"
+}