_pkgname=biboumi
pkgname="$_pkgname-git"
pkgver=9.0.r83.gbf958d0
pkgrel=1
pkgdesc="XMPP gateway to IRC"
arch=('x86_64' 'armv7h' 'aarch64')
url="https://biboumi.codeberg.page/"
license=('ZLIB')
depends=('expat' 'libidn' 'udns' 'sqlite')
makedepends=('git' 'cmake')
backup=("etc/$_pkgname/$_pkgname.cfg")
install="$_pkgname.install"
source=("$_pkgname::git+https://codeberg.org/poezio/biboumi"
        'biboumi.install'
        'biboumi.sysusers')
sha256sums=('SKIP'
            '7a50498d059e72b68a93057c51dc0766d9e39229f85da68721c78857ad8ce329'
            '910e6dc344c10f9ded3c5319592a5aaa1616d961d825e7392a40aa4b37c81174')

pkgver() {
  cd $_pkgname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  local cmake_options=(
    -B build
    -S $_pkgname
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX=/usr
    -DSERVICE_USER=biboumi
    -DSERVICE_GROUP=jabber
    -DWITH_BOTAN=1
    -DWITH_LIBIDN=1
    -DWITH_SQLITE3=1
    -DWITH_UDNS=1
    -Wno-dev 
  )
  
  cmake "${cmake_options[@]}"
  cmake --build build
}

package() {
  cd $_pkgname
  install -dm755 "$pkgdir"/usr/share/doc/$_pkgname/
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$_pkgname/LICENSE
  install -Dm644 doc/*.rst "$pkgdir"/usr/share/doc/$_pkgname/
  install -Dm644 conf/biboumi.cfg "$pkgdir"/etc/$_pkgname/$_pkgname.cfg
  cd ..
  install -Dm644 biboumi.sysusers "$pkgdir"/usr/lib/sysusers.d/$_pkgname.conf

  DESTDIR="$pkgdir/" cmake --install build
}